Utilizamos cookies propias y de terceros. Al navegar entendemos que aceptas el uso de cookies. +Info.
Política de cookies
Proyecto AjpdSoft

· Inicio
· Buscar
· Contactar
· Cookies
· Descargas
· Foros
· Historia
· Nosotros
· Temas
· Top 10
· Trucos
· Tutoriales
· Usuario
· Wiki

Proyecto AjpdSoft: Foros

AjpdSoft :: Ver tema - Instalar Office 97 en Windows 2000/2003 para terminal server
Foros de discusión Buscar Perfil FAQ Iniciar sesión
Information Instalar Office 97 en Windows 2000/2003 para terminal server

Publicar nuevo tema Responder al tema
Foros de discusión » Windows 10, Windows 7, Windows Server 2010, W2008, W2003   
Ver tema anterior :: Ver tema siguiente
AutorMensaje
varios
Magnífico usuario


Registrado: Oct 10, 2006
Mensajes: 2092

Asunto: Instalar Office 97 en Windows 2000/2003 para terminal server Responder citando

Me gustaría saber si alguien sabe cómo instalar correctamente Microsoft Office 97 en Windows 2000 y 2003. Será para utilizarlo mediante Terminal Server. Me han comentado que hay que utilizar unos script y demás.
MensajePublicado:
Mar Nov 28, 2006 11:58 am
Top of PageVer perfil de usuario
alonsojpd
Administrador/Moderador


Registrado: Sep 16, 2003
Mensajes: 2687

Asunto: Re: Instalar Office 97 en Windows 2000/2003 para terminal se Responder citando



Anuncios



varios escribió:
Me gustaría saber si alguien sabe cómo instalar correctamente Microsoft Office 97 en Windows 2000 y 2003. Será para utilizarlo mediante Terminal Server. Me han comentado que hay que utilizar unos script y demás.



Los pasos a seguir para instalar Office 97 en Windows 2000/2003 para uso en Terminal Server son:

1. Desde Inicio - Ejecutar ponemos "change user /install" y pulsamos INTRO (para indicar a Windows 2000/2003 que vamos a instalar una aplicación).
2. Se instala Office 97, SIN reiniciar.
3. Se instalan los parches SR1 y SR2 (es recomendable, se pueden descargar de la web de Microsoft).
4. Desde Inicio - Ejecutar ponemos "change user /execute" para indicar a Windows que hemos terminado de instalar apliaciones.
5. Se ejecuta el script Office97.cmd, pedirá que se introduzca una letra de unidad, se introduce una letra que tengamos libre, por ejemplo "W:" en el parámetro y se guarda el fichero.
6. Se reiniciar el equipo.
7. Tras el reinicio, se copia el script Ofc97Usr.Cmd a %systemroot%\Application Compatibility Scripts\Logon y se ejecuta

Con estos pasos debería funcionar correctamente, el script habrá creado una unidad virtual, con el comando "subst".

El contenido de los dos script utilizados es (para utilizarlos copias el contenido y lo pegas en un fichero de texto plano y lo nombras adecuadamente, con extensión .cmd):


****************Office97.cmd******************
Código:
CHANGE USER /INSTALL

%1 %2 %3 %4 %5 %6 %7 %8

IF %ERRORLEVEL% NEQ 0 GOTO STATUSMIF

GOTO NOMIF

:STATUSMIF

if exist c:\sms.ini ISMIF32 -f <Nombre de programa> [-s 0 –d] "Errorlevel %ERRORLEVEL%"

:NOMIF

CHANGE USER /EXECUTE

rem El siguiente ejemplo de secuencia de comandos de Terminal Server para la compatibilidad con aplicaciones de Office 97 incluye cambios que permiten ejecutarlo en Systems Management Server. Consulte la descripción en el apéndice B, en las instrucciones de instalación del paso 13.

@Echo Off

CHANGE USER /INSTALL

%1 %2 %3 %4 %5 %6 %7 %8

IF %ERRORLEVEL% NEQ 0 GOTO STATUSMIF

GOTO NOMIF

:STATUSMIF

if exist c:\sms.ini ISMIF32 -f Office97 -s 0 -d "Errorlevel %ERRORLEVEL%"

:NOMIF

CHANGE USER /EXECUTE

Rem
Rem NOTA: los comandos CACLS de esta secuencia sólo son efectivos
Rem en particiones con formato NTFS.
Rem

Rem #########################################################################

Rem
Rem Comprueba que %RootDrive% está configurada y establecida para esta secuencia de comandos.
Rem

Call "%SystemRoot%\Application Compatibility Scripts\ChkRoot.Cmd"

Rem #########################################################################

Rem
Rem Obtiene la ubicación de instalación de Office 97 del Registro.
Rem Si no se encuentra, se supone que Office no está instalado y se muestra un mensaje de error.
Rem

..\ACRegL %Temp%\O97.Cmd O97INST "HKLM\Software\Microsoft\Office\8.0\Common\InstallRoot" "" ""

If Not ErrorLevel 1 Goto Cont0
Echo.
Echo No se encuentra la ubicación de la instalación de Office 97 en el Registro.
Echo Comprueba que Office 97 está instalado y ejecuta esta secuencia de comandos
Echo de nuevo.
Echo.
Pause
Goto Done

:Cont0
Call %Temp%\O97.Cmd
Del %Temp%\O97.Cmd >Nul: 2>&1

Rem #########################################################################

Rem
Rem Cambia la base de datos de sistema de Access 97 a sólo lectura. Esto permite que
Rem varios usuarios la usen simultáneamente. Sin embargo,
Rem también impide actualizar la base de datos del sistema, lo que
Rem normalmente se hace a través de la opción de menú Herramientas, Seguridad. Si necesita
Rem agregar usuarios, primero deberá restaurar el permiso de escritura en la
Rem base de datos del sistema.
Rem

If Not Exist %SystemRoot%\System32\System.Mdw Goto Cont1
cacls %SystemRoot%\System32\System.Mdw /E /P EveryOne:R >NUL: 2>&1
cacls %SystemRoot%\System32\System.Mdw /E /P Administrators:R >NUL: 2>&1
:Cont1

Rem #########################################################################

Rem
Rem Permite el acceso general de lectura a una DLL de sistema que Office 97
Rem actualiza.
Rem

If Exist %SystemRoot%\System32\OleAut32.Dll cacls %SystemRoot%\System32\OleAut32.Dll /E /T /G EveryOne:R >NUL: 2>&1

Rem #########################################################################

Rem
Rem Cambia los Asistentes de Powerpoint a sólo lectura para permitir más de una
Rem llamada simultánea al asistente.
Rem

If Exist "%O97INST%\Templates\Presentations\AutoContent Wizard.Pwz" Attrib +R "%O97INST%\Templates\Presentations\AutoContent Wizard.Pwz" >Nul: 2>&1
If Exist "%O97INST%\Office\Ppt2html.ppa" Attrib +R "%O97INST%\Office\Ppt2html.ppa" >Nul: 2>&1
If Exist "%O97INST%\Office\bshppt97.ppa" Attrib +R "%O97INST%\Office\bshppt97.ppa" >Nul: 2>&1
If Exist "%O97INST%\Office\geniwiz.ppa" Attrib +R "%O97INST%\Office\geniwiz.ppa" >Nul: 2>&1
If Exist "%O97INST%\Office\ppttools.ppa" Attrib +R "%O97INST%\Office\ppttools.ppa" >Nul: 2>&1

Rem #########################################################################

Rem
Rem Crea los archivos MsForms.Twd y RefEdit.Twd, necesarios para los
Rem complementos de Powerpoint y Excel (Archivo, Guardar como HTML, etc). Cuando se
Rem ejecute alguno de estos programas, reemplazará el archivo correspondiente por otro que
Rem contenga los datos necesarios.
Rem

If Exist %systemroot%\system32\MsForms.Twd Goto Cont2
Copy Nul: %systemroot%\system32\MsForms.Twd >Nul: 2>&1
Cacls %systemroot%\system32\MsForms.Twd /E /P EveryOne:F >Nul: 2>&1
:Cont2

If Exist %systemroot%\system32\RefEdit.Twd Goto Cont3
Copy Nul: %systemroot%\system32\RefEdit.Twd >Nul: 2>&1
Cacls %systemroot%\system32\RefEdit.Twd /E /P EveryOne:F >Nul: 2>&1
:Cont3

Rem #########################################################################

Rem
Rem Quita Find Fast del menú Inicio para todos los usuarios.
Rem Find Fast usa muchos recursos y afecta al rendimiento
Rem del sistema.
Rem

If Exist "%SystemRoot%\Profiles\All Users\Start Menu\Programs\Startup\Microsoft Find Fast.lnk" Del "%SystemRoot%\Profiles\All Users\Start Menu\Programs\Startup\Microsoft Find Fast.lnk" >Nul: 2>&1

Rem #########################################################################

Rem
Rem Cambia claves del Registro para que las rutas de acceso indiquen
Rem directorios específicos del usuario.
Rem

Rem Si no se está en modo de instalación, cambiar a modo de instalación.
Set __OrigMode=Install
ChgUsr /query > Nul:
if Not ErrorLevel 101 Goto Begin
Set __OrigMode=Exec
Change User /Install > Nul:
:Begin

..\acsr "#ROOTDRIVE#" "%RootDrive%" Template\Office97.Key Office97.Tmp
..\acsr "#INSTDIR#" "%O97INST%" Office97.Tmp Office97.Key
Del Office97.Tmp >Nul: 2>&1

regini Office97.key > Nul:

Rem Si el modo original era el de ejecución, vuelve al modo de ejecución.
If "%__OrigMode%" == "Exec" Change User /Execute > Nul:
Set __OrigMode=

Rem #########################################################################

Rem
Rem Actualiza Ofc97Usr.Cmd para reflejar el directorio de instalación actual y
Rem agregarlo a la secuencia de comandos UsrLogon.Cmd
Rem

..\acsr "#INSTDIR#" "%O97INST%" ..\Logon\Template\Ofc97Usr.Cmd ..\Logon\Ofc97Usr.Cmd

FindStr /I Ofc97Usr %SystemRoot%\System32\UsrLogon.Cmd >Nul: 2>&1
If Not ErrorLevel 1 Goto Skip1
Echo Call Ofc97Usr.Cmd >> %SystemRoot%\System32\UsrLogon.Cmd
:Skip1

Echo Ajuste de Microsoft Office 97 para aplicación multiusuario completado

:done

pause










****************Ofc97Usr.Cmd******************
Código:
Rem #########################################################################

Rem
Rem Copiar el arhivo "Microsoft Office Shortcut Bar.lnk" de la ra¡z de instalaci¢n de Office
Rem al men£ de inicio actual del usuario.
Rem

If Exist "%RootDrive%\Office97" Goto Skip0
If Exist "%USER_STARTUP%\Microsoft Office Shortcut Bar.lnk" Goto Skip0
If Not Exist "C:\Archivos de programa\Microsoft Office\Microsoft Office Shortcut Bar.lnk" Goto Skip0
Copy "C:\Archivos de programa\Microsoft Office\Microsoft Office Shortcut Bar.lnk" "%USER_STARTUP%\Microsoft Office Shortcut Bar.lnk" >Nul: 2>&1
:Skip0

Rem
Rem Crear directorios para datos espec¡ficos de aplicaci¢n en el
Rem directorio particular de usuario.
Rem

call TsMkUDir "%RootDrive%\Office97"
call TsMkUDir "%RootDrive%\Office97\Startup"



call TsMkUDir "%RootDrive%\Office97\Templates"

call TsMkuDir "%RootDrive%\Office97\XLStart"
call TsMkUDir "%RootDrive%\%MY_DOCUMENTS%"

Rem
Rem Copiar estos archivos de todas las plantillas de usuario a la ubicaci¢n actual de plantillas de usuario
Rem

If Not Exist "%UserProfile%\%TEMPLATES%\WINWORD8.DOC" copy "%ALLUSERSPROFILE%\%TEMPLATES%\WINWORD8.DOC" "%UserProfile%\%TEMPLATES%\" /Y >Nul: 2>&1
If Not Exist "%UserProfile%\%TEMPLATES%\EXCEL8.XLS" copy "%ALLUSERSPROFILE%\%TEMPLATES%\EXCEL8.XLS" "%UserProfile%\%TEMPLATES%\" /Y >Nul: 2>&1
If Not Exist "%UserProfile%\%TEMPLATES%\BINDER.OBD" copy "%ALLUSERSPROFILE%\%TEMPLATES%\BINDER.OBD" "%UserProfile%\%TEMPLATES%\" /Y >Nul: 2>&1

Rem
Rem Copiar las barras de herramientas al directorio particular de usuario, a menos que
Rem ya existan.
Rem

If Exist "%RootDrive%\Office97\ShortCut Bar" Goto Skip1
If Not Exist "C:\Archivos de programa\Microsoft Office\Office\ShortCut Bar" Goto Skip1
Xcopy "C:\Archivos de programa\Microsoft Office\Office\ShortCut Bar" "%RootDrive%\Office97\ShortCut Bar" /E /I >Nul: 2>&1
:Skip1

Rem
Rem Copiar el directorio de formas para que Outlook pueda utilizar Word como el editor
Rem

If Exist "%RootDrive%\Windows\Forms" Goto Skip2
If Not Exist "%SystemRoot%\Forms" Goto Skip2
Xcopy "%SystemRoot%\Forms" "%RootDrive%\Windows\Forms" /e /i >Nul: 2>&1
:Skip2

Rem
Rem Copiar ARTGALRY.CAG al directorio de usuario de windows
Rem

If Exist "%RootDrive%\Windows\ArtGalry.Cag" Goto Skip3
If Not Exist "%SystemRoot%\ArtGalry.Cag" Goto Skip3
Copy "%SystemRoot%\ArtGalry.Cag" "%RootDrive%\Windows\ArtGalry.Cag" >Nul: 2>&1
:Skip3

Rem
Rem Copiar archivo Custom.dic al directorio de usuario
Rem

If Exist "%RootDrive%\Office97\Custom.Dic" Goto Skip4
If Not Exist "C:\Archivos de programa\Microsoft Office\Office\Custom.Dic" Goto Skip4
Copy "C:\Archivos de programa\Microsoft Office\Office\Custom.Dic" "%RootDrive%\Office97\Custom.Dic" >Nul: 2>&1
:Skip4

Rem
Rem Copiar archivos gr ficos al directorio de usuario
Rem

If Exist "%RootDrive%\Office97\GR8GALRY.GRA" Goto Skip5
If Not Exist "C:\Archivos de programa\Microsoft Office\Office\GR8GALRY.GRA" Goto Skip5
Copy "C:\Archivos de programa\Microsoft Office\Office\GR8GALRY.GRA" "%RootDrive%\Office97\GR8GALRY.GRA" >Nul: 2>&1
:Skip5

If Exist "%RootDrive%\Office97\XL8GALRY.XLS" Goto Skip6
If Not Exist "C:\Archivos de programa\Microsoft Office\Office\XL8GALRY.XLS" Goto Skip6
Copy "C:\Archivos de programa\Microsoft Office\Office\XL8GALRY.XLS" "%RootDrive%\Office97\XL8GALRY.XLS" >Nul: 2>&1
:Skip6
MensajePublicado:
Mar Nov 28, 2006 12:20 pm
Top of PageVer perfil de usuario
Mostrar mensajes de anteriores:   
Todas las horas son GMT - 1 Horas
Publicar nuevo tema Responder al tema
Foros de discusión » Windows 10, Windows 7, Windows Server 2010, W2008, W2003  

Cambiar a:  
Key
  Puede publicar nuevos temas en este foro
No puede responder a temas en este foro
No puede editar sus mensajes en este foro
No puede borrar sus mensajes en este foro
No puede votar en encuestas en este foro
Este sitio web NO CONTIENE malware, todos los programas con código fuente aquí. Autor: Alonso Javier Pérez Díaz Google+ Síguenos en Google+